MOS memory cell

Transient of a static MOS memory cell being written and read.

A static MOS memory cell (level 1 MOSFETs) with its write and sense circuits. Pulses on the write (node 1), write-bar (node 2) and select (node 7) lines write the cell, whose storage nodes are 5 and 6.

Output

Date: Tue Sep 29 08:47:02  2026
Nominal temperature = 27
Operating temperature = 27
Total iterations = 347
Transient iterations = 335
Circuit Equations = 14
Transient timepoints = 164
Accepted timepoints = 155
Rejected timepoints = 9
Total Analysis Time = 0.002
Transient time = 0.002
matrix reordering time = 0
L-U decomposition time = 0.001
Matrix solve time = 0
transient L-U decomp time = 0.001
Transient solve time = 0
Transient iters per point = 0
Load time = 0.001
.options: no listing, rawfile was generated.

The circuit: examples/mosmem.cir

mosmem - mos memory cell
.width in=72
.opt abstol=1u
.opt acct list node
vdd 9 0 dc 5
vs 7 0 pulse(2 0 520ns 20ns 20ns 500ns 2000ns)
vw 1 0 pulse(0 2 20ns 20ns 500ns 200ns)
vwb 2 0 pulse(2 0 20ns 20ns 20ns 2000ns 2000ns)
m1 3 1 0 0 mod w=250u l=5u
m2 4 2 0 0 mod w=250u l=5u
m3 9 9 3 0 mod w=5u   l=5u
m4 9 9 4 0 mod w=5u   l=5u
m5 5 7 3 0 mod w=50u  l=5u
m6 6 7 4 0 mod w=50u  l=5u
m7 5 6 0 0 mod w=250u  l=5u
m8 6 5 0 0 mod w=250u  l=5u
m9 9 9 5 0 mod w=5u   l=5u
m10 9 9 6 0 mod w=5u  l=5u
m11 8 4 0 0 mod w=250u l=5u
m12 9 9 8 0 mod w=5u   l=5u
.model mod nmos(vto=0.5 phi=0.7 kp=1.0e-6 gamma=1.83 lambda=0.115
+   level=1 cgso=1u cgdo=1u cbd=50p cbs=50p)
.control
tran 20ns 2us
plot v(6) v(5) v(7) v(1) v(2) multiplot
.endc
.end

Run it with spice mosmem.cir, or open it with File › Load netlist in the Qt window. The plots and output above were made by util/mkexamples.py, which runs the deck in batch mode. All examples